Parent Directory | Revision Log
Revision 1.1 - (view) (download)
1 : | edgomez | 1.1 | ;/**************************************************************************** |
2 : | ; * | ||
3 : | ; * XVID MPEG-4 VIDEO CODEC | ||
4 : | ; * - MMX and XMM forward discrete cosine transform - | ||
5 : | ; * | ||
6 : | ; * Copyright(C) 2001 Peter Ross <pross@xvid.org> | ||
7 : | ; * 2004 Andre Werthmann <wertmann@aei.mpg.de> | ||
8 : | ; * | ||
9 : | ; * This program is free software; you can redistribute it and/or modify it | ||
10 : | ; * under the terms of the GNU General Public License as published by | ||
11 : | ; * the Free Software Foundation; either version 2 of the License, or | ||
12 : | ; * (at your option) any later version. | ||
13 : | ; * | ||
14 : | ; * This program is distributed in the hope that it will be useful, | ||
15 : | ; * but WITHOUT ANY WARRANTY; without even the implied warranty of | ||
16 : | ; * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | ||
17 : | ; * GNU General Public License for more details. | ||
18 : | ; * | ||
19 : | ; * You should have received a copy of the GNU General Public License | ||
20 : | ; * along with this program; if not, write to the Free Software | ||
21 : | ; * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA | ||
22 : | ; * | ||
23 : | ; * $Id$ | ||
24 : | ; * | ||
25 : | ; ***************************************************************************/ | ||
26 : | |||
27 : | ; **************************************************************************** | ||
28 : | ; | ||
29 : | ; Originally provided by Intel at AP-922 | ||
30 : | ; http://developer.intel.com/vtune/cbts/strmsimd/922down.htm | ||
31 : | ; (See more app notes at http://developer.intel.com/vtune/cbts/strmsimd/appnotes.htm) | ||
32 : | ; but in a limited edition. | ||
33 : | ; New macro implements a column part for precise iDCT | ||
34 : | ; The routine precision now satisfies IEEE standard 1180-1990. | ||
35 : | ; | ||
36 : | ; Copyright(C) 2000-2001 Peter Gubanov <peter@elecard.net.ru> | ||
37 : | ; Rounding trick Copyright(C) 2000 Michel Lespinasse <walken@zoy.org> | ||
38 : | ; | ||
39 : | ; http://www.elecard.com/peter/idct.html | ||
40 : | ; http://www.linuxvideo.org/mpeg2dec/ | ||
41 : | ; | ||
42 : | ; ***************************************************************************/ | ||
43 : | ; | ||
44 : | ; These examples contain code fragments for first stage iDCT 8x8 | ||
45 : | ; (for rows) and first stage DCT 8x8 (for columns) | ||
46 : | ; | ||
47 : | |||
48 : | BITS 64 | ||
49 : | |||
50 : | ;============================================================================= | ||
51 : | ; Macros and other preprocessor constants | ||
52 : | ;============================================================================= | ||
53 : | |||
54 : | %macro cglobal 1 | ||
55 : | %ifdef PREFIX | ||
56 : | %ifdef MARK_FUNCS | ||
57 : | global _%1:function %1.endfunc-%1 | ||
58 : | %define %1 _%1:function %1.endfunc-%1 | ||
59 : | %else | ||
60 : | global _%1 | ||
61 : | %define %1 _%1 | ||
62 : | %endif | ||
63 : | %else | ||
64 : | %ifdef MARK_FUNCS | ||
65 : | global %1:function %1.endfunc-%1 | ||
66 : | %else | ||
67 : | global %1 | ||
68 : | %endif | ||
69 : | %endif | ||
70 : | %endmacro | ||
71 : | |||
72 : | %define BITS_INV_ACC 5 ; 4 or 5 for IEEE | ||
73 : | %define SHIFT_INV_ROW 16 - BITS_INV_ACC | ||
74 : | %define SHIFT_INV_COL 1 + BITS_INV_ACC | ||
75 : | %define RND_INV_ROW 1024 * (6 - BITS_INV_ACC) ; 1 << (SHIFT_INV_ROW-1) | ||
76 : | %define RND_INV_COL 16 * (BITS_INV_ACC - 3) ; 1 << (SHIFT_INV_COL-1) | ||
77 : | %define RND_INV_CORR RND_INV_COL - 1 ; correction -1.0 and round | ||
78 : | |||
79 : | %define BITS_FRW_ACC 3 ; 2 or 3 for accuracy | ||
80 : | %define SHIFT_FRW_COL BITS_FRW_ACC | ||
81 : | %define SHIFT_FRW_ROW BITS_FRW_ACC + 17 | ||
82 : | %define RND_FRW_ROW 262144*(BITS_FRW_ACC - 1) ; 1 << (SHIFT_FRW_ROW-1) | ||
83 : | |||
84 : | ;============================================================================= | ||
85 : | ; Local Data (Read Only) | ||
86 : | ;============================================================================= | ||
87 : | |||
88 : | %ifdef FORMAT_COFF | ||
89 : | SECTION .rodata | ||
90 : | %else | ||
91 : | SECTION .rodata align=16 | ||
92 : | %endif | ||
93 : | |||
94 : | ;----------------------------------------------------------------------------- | ||
95 : | ; Various memory constants (trigonometric values or rounding values) | ||
96 : | ;----------------------------------------------------------------------------- | ||
97 : | |||
98 : | ALIGN 16 | ||
99 : | one_corr: | ||
100 : | dw 1, 1, 1, 1 | ||
101 : | round_inv_row: | ||
102 : | dd RND_INV_ROW, RND_INV_ROW | ||
103 : | round_inv_col: | ||
104 : | dw RND_INV_COL, RND_INV_COL, RND_INV_COL, RND_INV_COL | ||
105 : | round_inv_corr: | ||
106 : | dw RND_INV_CORR, RND_INV_CORR, RND_INV_CORR, RND_INV_CORR | ||
107 : | round_frw_row: | ||
108 : | dd RND_FRW_ROW, RND_FRW_ROW | ||
109 : | tg_1_16: | ||
110 : | dw 13036, 13036, 13036, 13036 ; tg * (2<<16) + 0.5 | ||
111 : | tg_2_16: | ||
112 : | dw 27146, 27146, 27146, 27146 ; tg * (2<<16) + 0.5 | ||
113 : | tg_3_16: | ||
114 : | dw -21746, -21746, -21746, -21746 ; tg * (2<<16) + 0.5 | ||
115 : | cos_4_16: | ||
116 : | dw -19195, -19195, -19195, -19195 ; cos * (2<<16) + 0.5 | ||
117 : | ocos_4_16: | ||
118 : | dw 23170, 23170, 23170, 23170 ; cos * (2<<15) + 0.5 | ||
119 : | otg_3_16: | ||
120 : | dw 21895, 21895, 21895, 21895 ; tg * (2<<16) + 0.5 | ||
121 : | |||
122 : | %if SHIFT_INV_ROW == 12 ; assume SHIFT_INV_ROW == 12 | ||
123 : | rounder_0: | ||
124 : | dd 65536, 65536 | ||
125 : | rounder_4: | ||
126 : | dd 0, 0 | ||
127 : | rounder_1: | ||
128 : | dd 7195, 7195 | ||
129 : | rounder_7 | ||
130 : | dd 1024, 1024 | ||
131 : | rounder_2: | ||
132 : | dd 4520, 4520 | ||
133 : | rounder_6: | ||
134 : | dd 1024, 1024 | ||
135 : | rounder_3: | ||
136 : | dd 2407, 2407 | ||
137 : | rounder_5: | ||
138 : | dd 240, 240 | ||
139 : | |||
140 : | %elif SHIFT_INV_ROW == 11 ; assume SHIFT_INV_ROW == 11 | ||
141 : | rounder_0: | ||
142 : | dd 65536, 65536 | ||
143 : | rounder_4: | ||
144 : | dd 0, 0 | ||
145 : | rounder_1: | ||
146 : | dd 3597, 3597 | ||
147 : | rounder_7: | ||
148 : | dd 512, 512 | ||
149 : | rounder_2: | ||
150 : | dd 2260, 2260 | ||
151 : | rounder_6: | ||
152 : | dd 512, 512 | ||
153 : | rounder_3: | ||
154 : | dd 1203, 1203 | ||
155 : | rounder_5: | ||
156 : | dd 120, 120 | ||
157 : | %else | ||
158 : | |||
159 : | %error invalid SHIFT_INV_ROW | ||
160 : | |||
161 : | %endif | ||
162 : | |||
163 : | ;----------------------------------------------------------------------------- | ||
164 : | ; | ||
165 : | ; The first stage iDCT 8x8 - inverse DCTs of rows | ||
166 : | ; | ||
167 : | ;----------------------------------------------------------------------------- | ||
168 : | ; The 8-point inverse DCT direct algorithm | ||
169 : | ;----------------------------------------------------------------------------- | ||
170 : | ; | ||
171 : | ; static const short w[32] = { | ||
172 : | ; FIX(cos_4_16), FIX(cos_2_16), FIX(cos_4_16), FIX(cos_6_16), | ||
173 : | ; FIX(cos_4_16), FIX(cos_6_16), -FIX(cos_4_16), -FIX(cos_2_16), | ||
174 : | ; FIX(cos_4_16), -FIX(cos_6_16), -FIX(cos_4_16), FIX(cos_2_16), | ||
175 : | ; FIX(cos_4_16), -FIX(cos_2_16), FIX(cos_4_16), -FIX(cos_6_16), | ||
176 : | ; FIX(cos_1_16), FIX(cos_3_16), FIX(cos_5_16), FIX(cos_7_16), | ||
177 : | ; FIX(cos_3_16), -FIX(cos_7_16), -FIX(cos_1_16), -FIX(cos_5_16), | ||
178 : | ; FIX(cos_5_16), -FIX(cos_1_16), FIX(cos_7_16), FIX(cos_3_16), | ||
179 : | ; FIX(cos_7_16), -FIX(cos_5_16), FIX(cos_3_16), -FIX(cos_1_16) }; | ||
180 : | ; | ||
181 : | ; #define DCT_8_INV_ROW(x, y) | ||
182 : | ; { | ||
183 : | ; int a0, a1, a2, a3, b0, b1, b2, b3; | ||
184 : | ; | ||
185 : | ; a0 =x[0]*w[0]+x[2]*w[1]+x[4]*w[2]+x[6]*w[3]; | ||
186 : | ; a1 =x[0]*w[4]+x[2]*w[5]+x[4]*w[6]+x[6]*w[7]; | ||
187 : | ; a2 = x[0] * w[ 8] + x[2] * w[ 9] + x[4] * w[10] + x[6] * w[11]; | ||
188 : | ; a3 = x[0] * w[12] + x[2] * w[13] + x[4] * w[14] + x[6] * w[15]; | ||
189 : | ; b0 = x[1] * w[16] + x[3] * w[17] + x[5] * w[18] + x[7] * w[19]; | ||
190 : | ; b1 = x[1] * w[20] + x[3] * w[21] + x[5] * w[22] + x[7] * w[23]; | ||
191 : | ; b2 = x[1] * w[24] + x[3] * w[25] + x[5] * w[26] + x[7] * w[27]; | ||
192 : | ; b3 = x[1] * w[28] + x[3] * w[29] + x[5] * w[30] + x[7] * w[31]; | ||
193 : | ; | ||
194 : | ; y[0] = SHIFT_ROUND ( a0 + b0 ); | ||
195 : | ; y[1] = SHIFT_ROUND ( a1 + b1 ); | ||
196 : | ; y[2] = SHIFT_ROUND ( a2 + b2 ); | ||
197 : | ; y[3] = SHIFT_ROUND ( a3 + b3 ); | ||
198 : | ; y[4] = SHIFT_ROUND ( a3 - b3 ); | ||
199 : | ; y[5] = SHIFT_ROUND ( a2 - b2 ); | ||
200 : | ; y[6] = SHIFT_ROUND ( a1 - b1 ); | ||
201 : | ; y[7] = SHIFT_ROUND ( a0 - b0 ); | ||
202 : | ; } | ||
203 : | ; | ||
204 : | ;----------------------------------------------------------------------------- | ||
205 : | ; | ||
206 : | ; In this implementation the outputs of the iDCT-1D are multiplied | ||
207 : | ; for rows 0,4 - by cos_4_16, | ||
208 : | ; for rows 1,7 - by cos_1_16, | ||
209 : | ; for rows 2,6 - by cos_2_16, | ||
210 : | ; for rows 3,5 - by cos_3_16 | ||
211 : | ; and are shifted to the left for better accuracy | ||
212 : | ; | ||
213 : | ; For the constants used, | ||
214 : | ; FIX(float_const) = (short) (float_const * (1<<15) + 0.5) | ||
215 : | ; | ||
216 : | ;----------------------------------------------------------------------------- | ||
217 : | |||
218 : | ;----------------------------------------------------------------------------- | ||
219 : | ; Tables for xmm processors | ||
220 : | ;----------------------------------------------------------------------------- | ||
221 : | |||
222 : | ; %3 for rows 0,4 - constants are multiplied by cos_4_16 | ||
223 : | tab_i_04_xmm: | ||
224 : | dw 16384, 21407, 16384, 8867 ; movq-> w05 w04 w01 w00 | ||
225 : | dw 16384, 8867, -16384, -21407 ; w07 w06 w03 w02 | ||
226 : | dw 16384, -8867, 16384, -21407 ; w13 w12 w09 w08 | ||
227 : | dw -16384, 21407, 16384, -8867 ; w15 w14 w11 w10 | ||
228 : | dw 22725, 19266, 19266, -4520 ; w21 w20 w17 w16 | ||
229 : | dw 12873, 4520, -22725, -12873 ; w23 w22 w19 w18 | ||
230 : | dw 12873, -22725, 4520, -12873 ; w29 w28 w25 w24 | ||
231 : | dw 4520, 19266, 19266, -22725 ; w31 w30 w27 w26 | ||
232 : | |||
233 : | ; %3 for rows 1,7 - constants are multiplied by cos_1_16 | ||
234 : | tab_i_17_xmm: | ||
235 : | dw 22725, 29692, 22725, 12299 ; movq-> w05 w04 w01 w00 | ||
236 : | dw 22725, 12299, -22725, -29692 ; w07 w06 w03 w02 | ||
237 : | dw 22725, -12299, 22725, -29692 ; w13 w12 w09 w08 | ||
238 : | dw -22725, 29692, 22725, -12299 ; w15 w14 w11 w10 | ||
239 : | dw 31521, 26722, 26722, -6270 ; w21 w20 w17 w16 | ||
240 : | dw 17855, 6270, -31521, -17855 ; w23 w22 w19 w18 | ||
241 : | dw 17855, -31521, 6270, -17855 ; w29 w28 w25 w24 | ||
242 : | dw 6270, 26722, 26722, -31521 ; w31 w30 w27 w26 | ||
243 : | |||
244 : | ; %3 for rows 2,6 - constants are multiplied by cos_2_16 | ||
245 : | tab_i_26_xmm: | ||
246 : | dw 21407, 27969, 21407, 11585 ; movq-> w05 w04 w01 w00 | ||
247 : | dw 21407, 11585, -21407, -27969 ; w07 w06 w03 w02 | ||
248 : | dw 21407, -11585, 21407, -27969 ; w13 w12 w09 w08 | ||
249 : | dw -21407, 27969, 21407, -11585 ; w15 w14 w11 w10 | ||
250 : | dw 29692, 25172, 25172, -5906 ; w21 w20 w17 w16 | ||
251 : | dw 16819, 5906, -29692, -16819 ; w23 w22 w19 w18 | ||
252 : | dw 16819, -29692, 5906, -16819 ; w29 w28 w25 w24 | ||
253 : | dw 5906, 25172, 25172, -29692 ; w31 w30 w27 w26 | ||
254 : | |||
255 : | ; %3 for rows 3,5 - constants are multiplied by cos_3_16 | ||
256 : | tab_i_35_xmm: | ||
257 : | dw 19266, 25172, 19266, 10426 ; movq-> w05 w04 w01 w00 | ||
258 : | dw 19266, 10426, -19266, -25172 ; w07 w06 w03 w02 | ||
259 : | dw 19266, -10426, 19266, -25172 ; w13 w12 w09 w08 | ||
260 : | dw -19266, 25172, 19266, -10426 ; w15 w14 w11 w10 | ||
261 : | dw 26722, 22654, 22654, -5315 ; w21 w20 w17 w16 | ||
262 : | dw 15137, 5315, -26722, -15137 ; w23 w22 w19 w18 | ||
263 : | dw 15137, -26722, 5315, -15137 ; w29 w28 w25 w24 | ||
264 : | dw 5315, 22654, 22654, -26722 ; w31 w30 w27 w26 | ||
265 : | |||
266 : | ;============================================================================= | ||
267 : | ; Helper macros for the code | ||
268 : | ;============================================================================= | ||
269 : | |||
270 : | ;----------------------------------------------------------------------------- | ||
271 : | ; DCT_8_INV_ROW_XMM INP, OUT, TABLE, ROUNDER | ||
272 : | ;----------------------------------------------------------------------------- | ||
273 : | |||
274 : | %macro DCT_8_INV_ROW_XMM 4 | ||
275 : | movq mm0, [%1] ; 0 ; x3 x2 x1 x0 | ||
276 : | movq mm1, [%1+8] ; 1 ; x7 x6 x5 x4 | ||
277 : | movq mm2, mm0 ; 2 ; x3 x2 x1 x0 | ||
278 : | movq mm3, [%3] ; 3 ; w05 w04 w01 w00 | ||
279 : | pshufw mm0, mm0, 10001000b ; x2 x0 x2 x0 | ||
280 : | movq mm4, [%3+8] ; 4 ; w07 w06 w03 w02 | ||
281 : | movq mm5, mm1 ; 5 ; x7 x6 x5 x4 | ||
282 : | pmaddwd mm3, mm0 ; x2*w05+x0*w04 x2*w01+x0*w00 | ||
283 : | movq mm6, [%3+32] ; 6 ; w21 w20 w17 w16 | ||
284 : | pshufw mm1, mm1, 10001000b ; x6 x4 x6 x4 | ||
285 : | pmaddwd mm4, mm1 ; x6*w07+x4*w06 x6*w03+x4*w02 | ||
286 : | movq mm7, [%3+40] ; 7 ; w23 w22 w19 w18 | ||
287 : | pshufw mm2, mm2, 11011101b ; x3 x1 x3 x1 | ||
288 : | pmaddwd mm6, mm2 ; x3*w21+x1*w20 x3*w17+x1*w16 | ||
289 : | pshufw mm5, mm5, 11011101b ; x7 x5 x7 x5 | ||
290 : | pmaddwd mm7, mm5 ; x7*w23+x5*w22 x7*w19+x5*w18 | ||
291 : | paddd mm3, [%4] ; +%4 | ||
292 : | pmaddwd mm0, [%3+16] ; x2*w13+x0*w12 x2*w09+x0*w08 | ||
293 : | paddd mm3, mm4 ; 4 ; a1=sum(even1) a0=sum(even0) | ||
294 : | pmaddwd mm1, [%3+24] ; x6*w15+x4*w14 x6*w11+x4*w10 | ||
295 : | movq mm4, mm3 ; 4 ; a1 a0 | ||
296 : | pmaddwd mm2, [%3+48] ; x3*w29+x1*w28 x3*w25+x1*w24 | ||
297 : | paddd mm6, mm7 ; 7 ; b1=sum(odd1) b0=sum(odd0) | ||
298 : | pmaddwd mm5, [%3+56] ; x7*w31+x5*w30 x7*w27+x5*w26 | ||
299 : | paddd mm3, mm6 ; a1+b1 a0+b0 | ||
300 : | paddd mm0, [%4] ; +%4 | ||
301 : | psrad mm3, SHIFT_INV_ROW ; y1=a1+b1 y0=a0+b0 | ||
302 : | paddd mm0, mm1 ; 1 ; a3=sum(even3) a2=sum(even2) | ||
303 : | psubd mm4, mm6 ; 6 ; a1-b1 a0-b0 | ||
304 : | movq mm7, mm0 ; 7 ; a3 a2 | ||
305 : | paddd mm2, mm5 ; 5 ; b3=sum(odd3) b2=sum(odd2) | ||
306 : | paddd mm0, mm2 ; a3+b3 a2+b2 | ||
307 : | psrad mm4, SHIFT_INV_ROW ; y6=a1-b1 y7=a0-b0 | ||
308 : | psubd mm7, mm2 ; 2 ; a3-b3 a2-b2 | ||
309 : | psrad mm0, SHIFT_INV_ROW ; y3=a3+b3 y2=a2+b2 | ||
310 : | psrad mm7, SHIFT_INV_ROW ; y4=a3-b3 y5=a2-b2 | ||
311 : | packssdw mm3, mm0 ; 0 ; y3 y2 y1 y0 | ||
312 : | packssdw mm7, mm4 ; 4 ; y6 y7 y4 y5 | ||
313 : | movq [%2], mm3 ; 3 ; save y3 y2 y1 y0 | ||
314 : | pshufw mm7, mm7, 10110001b ; y7 y6 y5 y4 | ||
315 : | movq [%2+8], mm7 ; 7 ; save y7 y6 y5 y4 | ||
316 : | %endmacro | ||
317 : | |||
318 : | ;----------------------------------------------------------------------------- | ||
319 : | ; | ||
320 : | ; The first stage DCT 8x8 - forward DCTs of columns | ||
321 : | ; | ||
322 : | ; The %2puts are multiplied | ||
323 : | ; for rows 0,4 - on cos_4_16, | ||
324 : | ; for rows 1,7 - on cos_1_16, | ||
325 : | ; for rows 2,6 - on cos_2_16, | ||
326 : | ; for rows 3,5 - on cos_3_16 | ||
327 : | ; and are shifted to the left for rise of accuracy | ||
328 : | ; | ||
329 : | ;----------------------------------------------------------------------------- | ||
330 : | ; | ||
331 : | ; The 8-point scaled forward DCT algorithm (26a8m) | ||
332 : | ; | ||
333 : | ;----------------------------------------------------------------------------- | ||
334 : | ; | ||
335 : | ; #define DCT_8_FRW_COL(x, y) | ||
336 : | ;{ | ||
337 : | ; short t0, t1, t2, t3, t4, t5, t6, t7; | ||
338 : | ; short tp03, tm03, tp12, tm12, tp65, tm65; | ||
339 : | ; short tp465, tm465, tp765, tm765; | ||
340 : | ; | ||
341 : | ; t0 = LEFT_SHIFT ( x[0] + x[7] ); | ||
342 : | ; t1 = LEFT_SHIFT ( x[1] + x[6] ); | ||
343 : | ; t2 = LEFT_SHIFT ( x[2] + x[5] ); | ||
344 : | ; t3 = LEFT_SHIFT ( x[3] + x[4] ); | ||
345 : | ; t4 = LEFT_SHIFT ( x[3] - x[4] ); | ||
346 : | ; t5 = LEFT_SHIFT ( x[2] - x[5] ); | ||
347 : | ; t6 = LEFT_SHIFT ( x[1] - x[6] ); | ||
348 : | ; t7 = LEFT_SHIFT ( x[0] - x[7] ); | ||
349 : | ; | ||
350 : | ; tp03 = t0 + t3; | ||
351 : | ; tm03 = t0 - t3; | ||
352 : | ; tp12 = t1 + t2; | ||
353 : | ; tm12 = t1 - t2; | ||
354 : | ; | ||
355 : | ; y[0] = tp03 + tp12; | ||
356 : | ; y[4] = tp03 - tp12; | ||
357 : | ; | ||
358 : | ; y[2] = tm03 + tm12 * tg_2_16; | ||
359 : | ; y[6] = tm03 * tg_2_16 - tm12; | ||
360 : | ; | ||
361 : | ; tp65 =(t6 +t5 )*cos_4_16; | ||
362 : | ; tm65 =(t6 -t5 )*cos_4_16; | ||
363 : | ; | ||
364 : | ; tp765 = t7 + tp65; | ||
365 : | ; tm765 = t7 - tp65; | ||
366 : | ; tp465 = t4 + tm65; | ||
367 : | ; tm465 = t4 - tm65; | ||
368 : | ; | ||
369 : | ; y[1] = tp765 + tp465 * tg_1_16; | ||
370 : | ; y[7] = tp765 * tg_1_16 - tp465; | ||
371 : | ; y[5] = tm765 * tg_3_16 + tm465; | ||
372 : | ; y[3] = tm765 - tm465 * tg_3_16; | ||
373 : | ;} | ||
374 : | ; | ||
375 : | ;----------------------------------------------------------------------------- | ||
376 : | |||
377 : | ;----------------------------------------------------------------------------- | ||
378 : | ; DCT_8_INV_COL_4 INP,OUT | ||
379 : | ;----------------------------------------------------------------------------- | ||
380 : | |||
381 : | %macro DCT_8_INV_COL 2 | ||
382 : | movq mm0, [tg_3_16 wrt rip] | ||
383 : | movq mm3, [%1+16*3] | ||
384 : | movq mm1, mm0 ; tg_3_16 | ||
385 : | movq mm5, [%1+16*5] | ||
386 : | pmulhw mm0, mm3 ; x3*(tg_3_16-1) | ||
387 : | movq mm4, [tg_1_16 wrt rip] | ||
388 : | pmulhw mm1, mm5 ; x5*(tg_3_16-1) | ||
389 : | movq mm7, [%1+16*7] | ||
390 : | movq mm2, mm4 ; tg_1_16 | ||
391 : | movq mm6, [%1+16*1] | ||
392 : | pmulhw mm4, mm7 ; x7*tg_1_16 | ||
393 : | paddsw mm0, mm3 ; x3*tg_3_16 | ||
394 : | pmulhw mm2, mm6 ; x1*tg_1_16 | ||
395 : | paddsw mm1, mm3 ; x3+x5*(tg_3_16-1) | ||
396 : | psubsw mm0, mm5 ; x3*tg_3_16-x5 = tm35 | ||
397 : | movq mm3, [ocos_4_16 wrt rip] | ||
398 : | paddsw mm1, mm5 ; x3+x5*tg_3_16 = tp35 | ||
399 : | paddsw mm4, mm6 ; x1+tg_1_16*x7 = tp17 | ||
400 : | psubsw mm2, mm7 ; x1*tg_1_16-x7 = tm17 | ||
401 : | movq mm5, mm4 ; tp17 | ||
402 : | movq mm6, mm2 ; tm17 | ||
403 : | paddsw mm5, mm1 ; tp17+tp35 = b0 | ||
404 : | psubsw mm6, mm0 ; tm17-tm35 = b3 | ||
405 : | psubsw mm4, mm1 ; tp17-tp35 = t1 | ||
406 : | paddsw mm2, mm0 ; tm17+tm35 = t2 | ||
407 : | movq mm7, [tg_2_16 wrt rip] | ||
408 : | movq mm1, mm4 ; t1 | ||
409 : | movq [%2+3*16], mm5 ; save b0 | ||
410 : | paddsw mm1, mm2 ; t1+t2 | ||
411 : | movq [%2+5*16], mm6 ; save b3 | ||
412 : | psubsw mm4, mm2 ; t1-t2 | ||
413 : | movq mm5, [%1+2*16] | ||
414 : | movq mm0, mm7 ; tg_2_16 | ||
415 : | movq mm6, [%1+6*16] | ||
416 : | pmulhw mm0, mm5 ; x2*tg_2_16 | ||
417 : | pmulhw mm7, mm6 ; x6*tg_2_16 | ||
418 : | ; slot | ||
419 : | pmulhw mm1, mm3 ; ocos_4_16*(t1+t2) = b1/2 | ||
420 : | ; slot | ||
421 : | movq mm2, [%1+0*16] | ||
422 : | pmulhw mm4, mm3 ; ocos_4_16*(t1-t2) = b2/2 | ||
423 : | psubsw mm0, mm6 ; t2*tg_2_16-x6 = tm26 | ||
424 : | movq mm3, mm2 ; x0 | ||
425 : | movq mm6, [%1+4*16] | ||
426 : | paddsw mm7, mm5 ; x2+x6*tg_2_16 = tp26 | ||
427 : | paddsw mm2, mm6 ; x0+x4 = tp04 | ||
428 : | psubsw mm3, mm6 ; x0-x4 = tm04 | ||
429 : | movq mm5, mm2 ; tp04 | ||
430 : | movq mm6, mm3 ; tm04 | ||
431 : | psubsw mm2, mm7 ; tp04-tp26 = a3 | ||
432 : | paddsw mm3, mm0 ; tm04+tm26 = a1 | ||
433 : | paddsw mm1, mm1 ; b1 | ||
434 : | paddsw mm4, mm4 ; b2 | ||
435 : | paddsw mm5, mm7 ; tp04+tp26 = a0 | ||
436 : | psubsw mm6, mm0 ; tm04-tm26 = a2 | ||
437 : | movq mm7, mm3 ; a1 | ||
438 : | movq mm0, mm6 ; a2 | ||
439 : | paddsw mm3, mm1 ; a1+b1 | ||
440 : | paddsw mm6, mm4 ; a2+b2 | ||
441 : | psraw mm3, SHIFT_INV_COL ; dst1 | ||
442 : | psubsw mm7, mm1 ; a1-b1 | ||
443 : | psraw mm6, SHIFT_INV_COL ; dst2 | ||
444 : | psubsw mm0, mm4 ; a2-b2 | ||
445 : | movq mm1, [%2+3*16] ; load b0 | ||
446 : | psraw mm7, SHIFT_INV_COL ; dst6 | ||
447 : | movq mm4, mm5 ; a0 | ||
448 : | psraw mm0, SHIFT_INV_COL ; dst5 | ||
449 : | movq [%2+1*16], mm3 | ||
450 : | paddsw mm5, mm1 ; a0+b0 | ||
451 : | movq [%2+2*16], mm6 | ||
452 : | psubsw mm4, mm1 ; a0-b0 | ||
453 : | movq mm3, [%2+5*16] ; load b3 | ||
454 : | psraw mm5, SHIFT_INV_COL ; dst0 | ||
455 : | movq mm6, mm2 ; a3 | ||
456 : | psraw mm4, SHIFT_INV_COL ; dst7 | ||
457 : | movq [%2+5*16], mm0 | ||
458 : | paddsw mm2, mm3 ; a3+b3 | ||
459 : | movq [%2+6*16], mm7 | ||
460 : | psubsw mm6, mm3 ; a3-b3 | ||
461 : | movq [%2+0*16], mm5 | ||
462 : | psraw mm2, SHIFT_INV_COL ; dst3 | ||
463 : | movq [%2+7*16], mm4 | ||
464 : | psraw mm6, SHIFT_INV_COL ; dst4 | ||
465 : | movq [%2+3*16], mm2 | ||
466 : | movq [%2+4*16], mm6 | ||
467 : | %endmacro | ||
468 : | |||
469 : | ;============================================================================= | ||
470 : | ; Code | ||
471 : | ;============================================================================= | ||
472 : | |||
473 : | SECTION .text align=16 | ||
474 : | |||
475 : | cglobal idct_x86_64 | ||
476 : | |||
477 : | ;----------------------------------------------------------------------------- | ||
478 : | ; void idct_xmm(uint16_t block[64]); | ||
479 : | ;----------------------------------------------------------------------------- | ||
480 : | |||
481 : | ALIGN 16 | ||
482 : | idct_x86_64: | ||
483 : | mov rax, rdi ; block[] | ||
484 : | |||
485 : | ;; Process each row | ||
486 : | lea rsi, [tab_i_04_xmm wrt rip] | ||
487 : | lea rdi, [rounder_0 wrt rip] | ||
488 : | DCT_8_INV_ROW_XMM rax+0*16, rax+0*16, rsi, rdi | ||
489 : | |||
490 : | lea rsi, [tab_i_17_xmm wrt rip] | ||
491 : | lea rdi, [rounder_1 wrt rip] | ||
492 : | DCT_8_INV_ROW_XMM rax+1*16, rax+1*16, rsi, rdi | ||
493 : | |||
494 : | lea rsi, [tab_i_26_xmm wrt rip] | ||
495 : | lea rdi, [rounder_2 wrt rip] | ||
496 : | DCT_8_INV_ROW_XMM rax+2*16, rax+2*16, rsi, rdi | ||
497 : | |||
498 : | lea rsi, [tab_i_35_xmm wrt rip] | ||
499 : | lea rdi, [rounder_3 wrt rip] | ||
500 : | DCT_8_INV_ROW_XMM rax+3*16, rax+3*16, rsi, rdi | ||
501 : | |||
502 : | lea rsi, [tab_i_04_xmm wrt rip] | ||
503 : | lea rdi, [rounder_4 wrt rip] | ||
504 : | DCT_8_INV_ROW_XMM rax+4*16, rax+4*16, rsi, rdi | ||
505 : | |||
506 : | lea rsi, [tab_i_35_xmm wrt rip] | ||
507 : | lea rdi, [rounder_5 wrt rip] | ||
508 : | DCT_8_INV_ROW_XMM rax+5*16, rax+5*16, rsi, rdi | ||
509 : | |||
510 : | lea rsi, [tab_i_26_xmm wrt rip] | ||
511 : | lea rdi, [rounder_6 wrt rip] | ||
512 : | DCT_8_INV_ROW_XMM rax+6*16, rax+6*16, rsi, rdi | ||
513 : | |||
514 : | lea rsi, [tab_i_17_xmm wrt rip] | ||
515 : | lea rdi, [rounder_7 wrt rip] | ||
516 : | DCT_8_INV_ROW_XMM rax+7*16, rax+7*16, rsi, rdi | ||
517 : | |||
518 : | |||
519 : | ;; Process the columns (4 at a time) | ||
520 : | DCT_8_INV_COL rax+0, rax+0 | ||
521 : | DCT_8_INV_COL rax+8, rax+8 | ||
522 : | |||
523 : | ret | ||
524 : | .endfunc | ||
525 : |
No admin address has been configured | ViewVC Help |
Powered by ViewVC 1.0.4 |